[weatherbug_getstations] at tagSwap.net: Open Source Lasso Code

[weatherbug_getstations]

Description

Link: [weatherbug_getstations]

Author: Jason Huck

Category: Utility

Version: 8.x

License:

Posted: May. 08, 2006

Updated: Jan. 01, 0001

More by this author...

Returns a list of WeatherBug stations in a zip code. Requires a valid WeatherBug API Key.

Parameters

-key	string, required	A valid WeatherBug API key.
-zip	string, required	The zip code to use in the search.

Sample Usage

var('stations') = weatherbug_getstations(
	-key=$key,
	-zip=$zip
);

iterate($stations, local('s'));
	iterate(#s->keys, local('i'));
		#i + ': ' + #s->find(#i) + '<br>\n';
	/iterate;
	
	'<br>\n' * 2;
/iterate;

Source Code

Click the "Download" button below to retrieve a copy of this tag, including the complete documentation and sample usage shown on this page. Place the downloaded ".inc" file in your LassoStartup folder, restart Lasso, and you can begin using this tag immediately.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

define_tag(
	'getstations',
	-namespace='weatherbug_',
	-required='key',
	-required='zip',
	-priority='replace',
	-description='Returns a list of WeatherBug stations in a zip code.'
);
	local('url' = 'http://' + #key + '.api.wxbug.net/getStations.aspx');
	local('getparams') = array(
		'acode' = #key,
		'zipcode' = #zip
	);
	
	local('response') = include_url(
		#url,
		-getparams=#getparams
	);
	
	#response->replace(' xmlns:aws="http://www.aws.com/aws"','')&replace('aws:','');
	
	local('xmldata') = xml(#response);
	local('stations') = #xmldata->extract('//station');
	local('out' = array);
	
	local('fields') = array(
		'id',
		'name',
		'city',
		'state',
		'zipcode',
		'distance',
		'station-type'
	);
	
	iterate(#stations, local('s'));
		#s = xml('<?xml version="1.0" encoding="utf-8" ?>' + #s);
	
		local('map' = map);
		
		iterate(#fields, local('f'));
			local('v') = string(#s->extract('//@' + #f)->first)->split('="')->second;
			#v->removetrailing('"');
			#map->insert(#f = #v);
		/iterate;
		
		#out->insert(#map);
	/iterate;
	
	return(@#out);
/define_tag;

Related Tags

Comments

none