[

define_tag:'lp_lasso_version',
	-description='Returns the Lasso version, edition and platform in a single string.',
	-priority='replace',
	-optional='version', // returns the version expressed as a decimal value
	-optional='compact'; // returns the Lasso version, edition and platform expressed as a 6-char string

	if: (local_defined:'version');
		local:'version_array' = (lasso_version: -lassoversion)->(split:'.');
		local:'return' = decimal;
		iterate: #version_array, local:'v';
			#return += (decimal: (decimal: #v) / (math_pow: 10, (loop_count - 1) * 2));			
		/iterate;
		return: #return;
	else: (local_defined:'compact');
		local:'return' = string;
		
		// edition
		if: (Lasso_Version: -LassoEdition)->(contains:'standard');
			#return += 'S';
		else: (Lasso_Version: -LassoEdition)->(contains:'developer');
			#return += 'D';
		else: (Lasso_Version: -LassoEdition)->(contains:'enterprise');
			#return += 'E';
		else;
			#return += 'U'; // unknown
		/if;

		// edition
		if: (Lasso_Version: -LassoPlatform)->(contains:'mac');
			#return += 'M';
		else: (Lasso_Version: -LassoPlatform)->(contains:'win');
			#return += 'W';
		else: (Lasso_Version: -LassoPlatform)->(contains:'lin');
			#return += 'L';
		else;
			#return += 'U'; // unknown
		/if;

		local:'version' = (string_findregexp:(Lasso_Version: -LassoVersion),-find='\\d')->(join:'');
		#version = (lp_string_pad: #version, 4, -padright, -padchar='0',-cropright);
		return: #return + #version;
	else;
		return: 'Lasso ' (Lasso_Version: -LassoEdition) ' ' (Lasso_Version: -LassoVersion) ' (' (Lasso_Version: -LassoPlatform) ')';
	/if;

/define_tag;

]