[google_map]
Description
The purpose of this tag is to access Google's Static Map API.
Refer to Google's Static Map API for map types, marker types, etc.
This ctag returns a static image file of your choosing of a Google Map. It will also overlay markers and paths.
Note: To find longitude and latitude coordinates of street addresses use the google_geocode ctag.
Parameters
-size
string, required Indicate height and width of map
-key
string, required Key to access Google Map API.
-center
string, optional A comma seperated string to indicate latitude and longitide of center of map
-zoom
string, optional Indicate zoom level (see API for details)
-format
string, optional Indicate image file type to be returned
-mapType
string, optional Indicate type of map to be returned (see API for details)
-markers
array, optional An array of longitude and latitude coordinates to place marker overlays on map (see API for details on sizes, color and types)
-path
array, optional An array of longitude and latitude coordinates to draw a path overlay on the map
-frame
boolean, optional When True a 5px blue border is drawn around the map
Sample Usage
google_map(
-size='475x400',
-key='MAPS_API_KEY',
-zoom='14',
-center='40.711614,-74.012318',
-mapType='mobile',
-markers=array('40.702147,-74.015794,reda', '40.711614,-74.012318,tinygreen', '40.713504,-74.005607,midyellowb'),
-path=array('40.702147,-74.015794', '40.713504,-74.005607'),
-pathColor='0x0000ff',
-pathWeight='8',
-format='gif',
-frame=true,
);
Source Code
Click the "Download" button below to retrieve a copy of this tag,
including the complete documentation and sample usage shown
on this page. Place the downloaded ".inc" file in your
LassoStartup folder, restart Lasso, and you can begin using this
tag immediately.
1
define_tag(
'map',
-namespace='google_',
-req='size',
-req='key',
-opt='center',
-opt='zoom',
-opt='format',
-opt='mapType',
-opt='markers', -type='array',
-opt='path', -type='array',
-opt='frame', -type='boolean',
-encodenone
);
!local_defined('center') ? local('center') = string;
!local_defined('zoom') ? local('zoom') = string;
!local_defined('format') ? local('format') = string;
!local_defined('mapType') ? local('mapType') = string;
!local_defined('markers') ? local('markers') = array;
!local_defined('path') ? local('path') = array;
!local_defined('pathColor') ? local('pathColor') = '0x0000ff';
!local_defined('pathWeight') ? local('pathWeight') = '5';
!local_defined('frame') ? local('frame') = false;
local('imgURL') = '<img src="http://maps.google.com/staticmap?size=' + #size + '&key=' + #key;
// add optional center of map
#center ? #imgURL += '¢er=' + #center;
// add zoom level to map (API defaults to 0 or world level)
#zoom ? #imgURL += '&zoom=' + #zoom;
// add optional image file format of map (API defaults to .gif)
#format ? #imgURL += '&format=' + #format;
// add optional type of map (API defaults to Mobile)
#mapType ? #imgURL += '&maptype=' + #mapType;
// if true adds optional blue 5px frame around map
#imgURL += '&frame=' + #frame;
// overlay markers on map (also indicate marker size, color and labels in array)
#markers->size > 0 ? #imgURL += '&markers=';
iterate(#markers, local('str'));
#imgURL += #str + '|';
/iterate;
#imgURL->removetrailing('|');
// overlay paths between two or more points on map (uses RGB color codes for path color)
#path->size > 1 ? #imgURL += '&path=rgb:' + #pathColor + ',weight:' + #pathWeight + '|';
iterate(#path, local('str'));
#imgURL += #str + '|';
/iterate;
#imgURL->removetrailing('|');
#imgURL += '" />';
return(#imgURL);
/define_tag;
Related Tags
Comments
none
