define_tag(
	'info',
	-namespace='cache_',
	-req='name', -copy,
	-opt='session',
	-opt='useglobal',
	-priority='replace',
	-description='Returns information about the specified cache.'
);
	// cache storage mechanism changed as of 8.5.6
	if(!lasso_tagexists('cache_maintenance'));
		// map elements: content, stat_fetch, type, id, stat_store, date
	
		// add the server name to the cache name if host-specific caches is enabled
		cache_preferences->find('_cache_host') == 'Y' ? #name += '|' + server_name;

		// return null if there are no caches or the specified cache does not exist		
		!global_defined('_Cache_Storage') || $_Cache_Storage->find(#name) == '' ? return;
		
		// return a reference to the specified cache
		return(@$_Cache_Storage->find(#name));
	else;
		!local_defined('useglobal') ? local('useglobal') = true;
	
		\cache_internal->eval;

		if(#useglobal);
			thread_atomic(globals->find(#c_prefix + 'fetch'));
				globals->insert((#c_prefix + 'fetch') = integer(globals->find(#c_prefix + 'fetch')) + 1);
				local('fetch') = globals->find(#c_prefix + 'fetch');
				local('content') = globals->find(#c_prefix + 'content');
				local('date') = globals->find(#c_prefix + 'date');
				local('store') = @globals->find(#c_prefix + 'store');
			/thread_atomic;
		else;
			vars->insert((#c_prefix + 'fetch') = integer(vars->find(#c_prefix + 'fetch')) + 1);
			local('fetch') = vars->find(#c_prefix + 'fetch');
			local('content') = vars->find(#c_prefix + 'content');
			local('date') = vars->find(#c_prefix + 'date');
			local('store') = @vars->find(#c_prefix + 'store');
		/if;
					
		local('out') = map(
			'content' = #content,
			'stat_fetch' = #fetch,
			'type' = #c_type,
			'id' = null,
			'stat_store' = #store,
			'date' = #date
		);
		
		return(#out);
	/if;
/define_tag;