<?Lassoscript


///////////////////////////////////////////////////////////////////////
//																	 //
// Fedex Tracker by Marc Pope < marc.pope@falconarea.net >			 //
// v1.0 - Created April 12, 2004									 //
//																	 //
// Free for personal/company use. Not for resale.				     //
// Required: Lasso Professional 7.x & Higher						 //
//																	 //
// This solution based on using the Fedex Tagged Transaction Format  //
//																	 //
// Download the Tagged Transaction Guide for more details:			 //
// www.fedex.com/us/solutions/wis/pdf/TagTransGuide.pdf?link=4		 //
//																	 //
// Thanks to the Lasso Community for ideas!							 //
//																	 //
///////////////////////////////////////////////////////////////////////



?>

<style type="text/css" media="screen"><!--
		.text  { font-size: 10px; font-family: Verdana, Helvetica, Geneva, Swiss, SunSans-Regular }
		.bold  { font-weight: bold; font-size: 10px; font-family: Verdana, Helvetica, Geneva, Swiss, SunSans-Regular }
		-->
</style>

<?Lassoscript

// Set variables from passed data
// format should be  track.lasso?trackNumb=0123456789012345

	var:'trackNumb'= (action_param:'trackNumb');


// header, change as needed.

'<span class="bold"><font size="4">Live Fedex Tracking Results: '+$trackNumb+'</font><br></span><hr>';


// only get results if a tracking number is supplied.

if: $trackNumb !='';

// build query for Fedex's Server

	var:'query'='0,"403"1534,"Y"1537,"' + $trackNumb + '"99,""';


// Get Tracking Data from Fedex

// Note: It is recommended that you acquire a meter number from Fedex
// although i'm not using one here and it still works.. so up to you.
// Using the new PostParams tag to get results.. thanks BlueWorld!

	var:'result'= (Include_URL: 'https://gateway.fedex.com/GatewayDC', -POSTParams=$query);
	

// Parse Results
// Fedex returns a very strange pattern, so we'll make it work

	protect;
		$result = (String_Replace: $result, -Find=',"', -Replace='|||');
		$result = (String_Replace: $result, -Find='"', -Replace='+++');
	/protect;


// build array of results

	var:'FDXArray'=(array);

	protect;
		var:'FDXArray'= $result->(Split:'+++');
	/protect;


// put the results array into a mapped array

var:'FDXmap'=(map);

loop: $FDXArray->(Size);

	var:'tempString'=$FDXArray->(get: (loopcount));
	var:'tempArray'=$tempString->(Split:'|||');
	var:'tempCode'=$tempArray->(Get:'1');
	
	if:$tempArray->(size) > '1';
		var:'tempResult'=$tempArray->(get:'2');
		else;
		var:'tempResult'='';
	/if;
	
	$FDXmap->(Insert: (var:'tempCode')=(var:'tempResult'));
	
/loop;


// display any errors from Fedex

if: $FDXMap->(find: '3') != '';

	'<br><font color="red" class="bold"><br>';
		$FDXMap->(Find: '3');
	'</font>';

else;


// now all the results are in a mapped array called $FDXMap
// see the Fedex Tagged Transaction Guide for code references
// make easy to read variables for the main ones
	
	var:'weight'=$FDXmap->(find:'1401-1'),
		'weightdesc'=$FDXmap->(find:'75-1'),
		'city'=$FDXmap->(find:'15-1'),
		'state'=$FDXmap->(find:'16-1'),
		'zip'=$FDXmap->(find:'17-1'),
		'country'=$FDXmap->(find:'50-1'),
		'UCN'=$FDXmap->(find:'1537-1-1'),
		'orderNumber'=$FDXmap->(find:'1537-1-2'),
		'packageID'=$FDXmap->(find:'1537-1-3'),
		'tempSDate'=$FDXmap->(find:'24-1'),
		'tempDDate'=$FDXmap->(find:'1720-1'),
		'tempDTime'=$FDXmap->(find:'1707-1'),
		'tempEDate'=$FDXmap->(find:'1339-1'),
		'tempETime'=$FDXmap->(find:'1340-1'),
		'tempRDate'=$FDXmap->(find:'1716-1'),
		'tempRTime'=$FDXmap->(find:'1717-1'),
		'serviceType'=$FDXmap->(find:'1704-1'),
		'items'=$FDXmap->(find:'116-1'),
		'signedFor'=$FDXmap->(find:'1706-1'),
		'serviceCode'=$FDXmap->(find:'3025-1');
		

// parse expected delivered date
// this part is messy, but it works.. sorry
// need to rewrite using date tags

var: 'expectedDate'='',
	 'expectedTime'='';
	 
if: $tempEDate !='';
	var: 'ExpectedDate'= $tempEDate->(substring: 5,2) + '/' +
						 $tempEDate->(substring: 7,2) + '/' +
						 $tempEDate->(substring: 1,4);
/if;

if: $tempETime !='';
	var: 'ExpectedTime'= $tempETime->(substring: 1,2) + ':' +
						 $tempETime->(substring: 3,2) + ':' +
						 $tempETime->(substring: 5,2);
/if;

var: 'reattemptDate'='',
	 'reattemptTime'='';
	 
if: $tempRDate !='';
	var: 'ReattemptDate'=$tempRDate->(substring: 5,2) + '/' +
						 $tempRDate->(substring: 7,2) + '/' +
						 $tempRDate->(substring: 1,4);
/if;

if: $tempRTime !='';
	var: 'ReattemptTime'=$tempRTime->(substring: 1,2) + ':' +
						 $tempRTime->(substring: 3,2) + ':' +
						 $tempRTime->(substring: 5,2);
/if;


// parse delivered date

var: 'deliveryDate'='',
	 'shipdate'='',
	 'deliveryTime'='';
	 
if: $tempDDate !='';
	var: 'DeliveryDate'= $tempDDate->(substring: 5,2) + '/' +
						 $tempDDate->(substring: 7,2) + '/' +
						 $tempDDate->(substring: 1,4);
/if;

if: $tempDTime !='';
	var: 'DeliveryTime'= $tempDTime->(substring: 1,2) + ':' +
						 $tempDTime->(substring: 3,2) + ':' +
						 $tempDTime->(substring: 5,2);
/if;

if: $tempSDate !='';
	var: 'ShipDate'= $tempSDate->(substring: 5,2) + '/' +
						 $tempSDate->(substring: 7,2) + '/' +
						 $tempSDate->(substring: 1,4);
/if;
	

// build a table of the info, modify as you wish
// note: not all fields are always populated
	
	'<table border="1" cellpadding="3" cellspacing="0" class="text">
		<tr>
			<td>Package Weight: ' + $weight + $weightDesc '</td>
			<td>Location: ' + $city + ', ' + $state + ' ' + $zip + '</td></tr>
		<tr>
			<td>UCN: ' + $UCN + '</td>
			<td>Country: ' + $country + '</td></tr>
		<tr>
			<td>Order #: ' + $OrderNumber + '</td>
			<td>Package ID: ' + $PackageID + '</td></tr>
		<tr>
			<td>Ship Date: ' + $ShipDate + '</td>
			<td>Delivered On: ' + $DeliveryDate + ' ' + $DeliveryTime + '</td></tr>
		<tr>
			<td>Reattempt Date: ' + $reattemptDate + ' ' + $reattemptTime + '</td>
			<td>Expected Date: ' + $expectedDate + ' ' + $expectedTime + '</td></tr>
		<tr>
			<td>Service Type: ' + $serviceType +  '</td>
			<td>Signed For: ' + $signedFor +  '</td></tr>
		<tr>
			<td>Service Code: ' + $serviceCode +  '</td>
			<td>Items: ' + $items +  '</td></tr></table><br>';
	
// now build scan history into some pretty tables
	
	// 1715-1 contains the number of scan history lines
	
	var:'historyItems'=integer:($FDXmap->(find:'1715-1'));
	
	if: $historyitems > 0;
	
	'<table border="1" cellpadding="3" cellspacing="0" class="text">';
	
			'<tr bgcolor="#DDDDDD" class="bold">';
			'<td>'+ 'Scan Date' +'</td>';
			'<td>'+ 'Scan Time' +'</td>';
			'<td>'+ 'Code' +'</td>';
			'<td>'+ 'Message' +'</td>';
			'<td>'+ 'City' +'</td>';
			'<td>'+ 'State' +'</td>';
			'<td>'+ 'Country' +'</td>';
			'<td>'+ 'Comment' +'</td>';
		'</tr>';
	
	loop: $historyitems;
	
		var: 'scanCode' =    $FDXmap->(find: ('1171-1-'+(loopcount)));
		var: 'scanMsg'  =    $FDXmap->(find: ('1159-1-'+(loopcount)));
		var: 'scanCity'  =   $FDXmap->(find: ('1160-1-'+(loopcount)));
		var: 'scanState'  =  $FDXmap->(find: ('1161-1-'+(loopcount)));
		var: 'scanCountry' = $FDXmap->(find: ('1164-1-'+(loopcount)));
		var: 'scanDate'  =   $FDXmap->(find: ('1162-1-'+(loopcount)));
		var: 'scanTime'  =   $FDXmap->(find: ('1163-1-'+(loopcount)));
		var: 'scanComments'= $FDXmap->(find: ('1711-1-'+(loopcount)));
		
		// reformat date
		
		if: $scanDate !='';
			var:'tempScanDate'= $scanDate;
			
			var: 'ScanDate'= $tempscanDate->(substring: 5,2) + '/' +
						 	 $tempscanDate->(substring: 7,2) + '/' +
						 	 $tempscanDate->(substring: 1,4);
		/if;

		// reformat time
		
		if: $scanTime !='';
			var:'tempScanTime'= $scanTime;
			
			var: 'ScanTime'= $tempscanTime->(substring: 1,2) + ':' +
						 	 $tempscanTime->(substring: 3,2) + ':' +
						 	 $tempscanTime->(substring: 5,2);
		/if;
		
		
		'<tr>';
			'<td>'+ $scanDate +'</td>';
			'<td>'+ $scanTime +'</td>';
			'<td>'+ $scanCode +'</td>';
			'<td>'+ $scanMsg +'</td>';
			'<td>'+ $scanCity +'</td>';
			'<td>'+ $scanState +'</td>';
			'<td>'+ $scanCountry +'</td>';
			'<td>'+ $scanComments +'</td>';
		'</tr>';

	/loop;
	
	'</table>';
	
	/if;
	
	/if;
	

/if;

?>